uses crt;

const max       = 5;
type  long_vek  = array[1..max] of real;
      short_vek = array[1..max-1] of real;

var  d,b        : long_vek;
     c,e        : short_vek;               { entspricht Matrix A }



procedure write_matrix(r:short_vek ; s:long_vek ; t:short_vek);
var i,k  : integer;
begin
 write(s[1]:8:3 ,' ', t[1]:8:3 , ' ');
 for i:=1 to max-2 do write(0:8,' ');      { Nullen in 1. Zeile anzeigen }
 writeln;

 for i:=2 to max-1 do
  begin
    for k:=1 to i-2 do  write(0:8,' ');    { linke Nullen anzeigen }
    write(r[i-1]:8:3, ' ', s[i]:8:3, ' ', t[i]:8:3 , ' ');
    for k:=2 to max-i do write(0:8,' ');   { rechte Nullen anzeigen }
    writeln;
  end;

 for i:=1 to max-2 do write(0:8,' ');      { Nullen in max. Zeile anzeigen }
 write(r[max-1]:8:3 ,' ', s[max]:8:3 , ' ');
 writeln; writeln;
end;                                       { of write_matrix }



procedure lies_vektoren;
var i,k :integer;
begin
 writeln('Geben Sie den Vektor c ein !');
 writeln;writeln;
 for i:=1 to max-1 do  begin  write('c[',i:1,']  ? '); readln(c[i]);  end;
 writeln;writeln;
 writeln('Geben Sie den Vektor d ein !');
 writeln;writeln;
 for i:=1 to max do  begin  write('d[',i:1,']  ? '); readln(d[i]);  end;
 writeln;writeln;
 writeln('Geben Sie den Vektor e ein !');
 writeln;writeln;
 for i:=1 to max-1 do  begin  write('e[',i:1,']  ? '); readln(e[i]);  end;
 writeln;writeln;
 writeln('Geben Sie den Vektor b ein !');
 writeln;writeln;
 for i:=1 to max do  begin  write('b[',i:1,']  ? '); readln(b[i]);  end;
end;     { of lies_vektoren }




procedure berechne_x;
var i :integer;
begin
 for i:=1 to max-1 do
   begin
     e[i]  :=e[i]/d[i];
     d[i+1]:=d[i+1]-c[i]*e[i];
   end;
 b[1]:=b[1]/d[1];
 for i:=2  to  max  do     b[i]:=(b[i]-c[i-1]*b[i-1])/d[i];
 for i:=max-1 downto 1 do  b[i]:=b[i]-e[i]*b[i+1];
end;                              { of berechne_x }



procedure write_x;
var i :integer;
begin
 writeln('                  ****** Loesung ****** '); writeln;
 for i:=1 to max do writeln( b[i]:10:5 );
end;



begin                             { main program }
clrscr;
 lies_vektoren;
 readln;
 clrscr;
 writeln('                  ****** Matrix A ****** '); writeln;
 write_matrix(c,d,e);
 readln;
 berechne_x;
 writeln;writeln;
 writeln('                  ****** Matrix L+R ****** '); writeln;
 write_matrix(c,d,e);
 writeln;writeln;
 write_x;
 readln;
end.