#!/usr/local/bin/perl
#
# pstree Perl version for Digital Unix
# (C) 1997 Erik Heinz, IKS GmbH Jena, <erik@iks-jena.de>
#
# 09/16/97
#
# 05/05/1998
# changed for Solaris 2.5.1 by René Scholz <Voland@Jena.Thur.de>

($NAME=$0) =~ s#.*/##;  # get basename from $0
use Getopt::Std;

$PS_CMD='/bin/ps -o uid -o pid -o ppid -o fname';

$USAGE=<<EOUSAGE;
Usage: $NAME [options]

Options: -h      Show this help.
	 -p      Print PID
	 -u      Print USER
	 -a      Print all processes
	 -A      Print ALL processes
	 -r pid  use pid as root for the tree
	 -G      Use vt100 graphic chars

EOUSAGE

$bold=`tput smso`;  $noatt=`tput sgr0`;
$alt=`tput smacs`;  $noalt=`tput rmacs`;
$enacs=`tput enacs`;

# this pid has no PPID:
$REELROOT=0;  # first PID: Linux=1? Solaris=0 Dec=0


do getopts('puhHaAGr:');
die $USAGE if($opt_h || $opt_H);

$PS_CMD.=" -a", $ROOT=1 if($opt_a);       # 0
$PS_CMD.=" -A", $ROOT=1 if($opt_A);       # 1
$PS_CMD.=" -A", $ROOT=$opt_r if($opt_r ne "");  # own root-pid
# else: take PPID from current shell:
$PS_CMD.=" -A", $ROOT=getppid unless($opt_a || $opt_A || $opt_r ne "");

read_list();

print_childs($ROOT,"");   # Root of Processes = pid(init)
                          # $ROOT=PID of starting shell (I hope)

print $noalt if($opt_G);
############################### END ############################


sub read_list
{
  open PSLIST, "$PS_CMD |";
  while (<PSLIST>)
    {
      my($uid,$pid,$ppid,$cmd)=split;
#      next if($pid eq 'PID'  || $pid==0 ||  $ppid eq $$);
      next if($pid eq 'PID');
      push @{$pchilds{$ppid}}, $pid;
      my $pinfo;
      if($opt_p) { $pinfo=$pid; }
      if($opt_u && $uid)
	{
	  my $name=getpwuid($uid);
	  if($pinfo) { $pinfo.=",$name"; }
	  else       { $pinfo = $name; }
	}
      if($pinfo) { $pcmd{$pid}="$cmd($pinfo)"; }
      else       { $pcmd{$pid}= $cmd; }
    }
  close PSLIST;
}


sub compress
{
  my @plist=@_;
  my $i;
  for ($i=0; $i<$#plist; $i++)
    {
      my $pid=$plist[$i];
      next if(@{$pchilds{$pid}});
      my $j=0; my $cmd=$pcmd{$pid};
      while (($pcmd{$plist[$i+1]} eq $cmd) &&
	     (! @{$pchilds{$plist[$i+1]}}) && ($i<$#plist))
	{
	  $j++; splice @plist, $i+1, 1;
	}
      if($j) { $j++; $pcmd{$pid}="$j*[$cmd]"; }
    }
  return @plist;
}



sub print_childs
# Use tput for printing better graphics
{
  my ($ppid, $pre, $lspc)=@_;
  my (@plist, $pid, $lcmd);

  if($opt_G)
    {
      print $enacs;
      $S=$alt   . "x"   . $noalt;
      $W=$alt   . "q"   . $noalt;
      $W3=$alt  . "qqq" . $noalt;
      $MPM=$alt . "qwq" . $noalt;
      $T=$alt   . "tq"  . $noalt;
      $M=$alt   . "mq"  . $noalt;
    }
  else  { $S="|";  $W="-"; $W3="---"; $MPM="-+-"; }
  
  $lcmd=$pcmd{$ppid};
  $pre.=' ' x length($lcmd);
  if($ppid>0)  # !=0
    {
      if($ppid==$ROOT) { print $lcmd; $pre.=" $S"; }
      else             { print $lspc, $lcmd; $pre.="  $S"; }
    }

  if(exists $pchilds{$ppid})
    {
      @plist=sort {$pcmd{$a} cmp $pcmd{$b}} @{$pchilds{$ppid}};
      @plist=compress(@plist) unless ($opt_p);
      if(@plist==1) { print_childs($plist[0], $pre, $W3); }
      else
	{
	  my ($i, $p0);
	  print_childs($plist[0], $pre, $MPM);
	  for ($i=1; $i<$#plist; $i++)
	    {
	      if(! $opt_G)
		{ print_childs($plist[$i], $pre, "${pre}-"); }
	      else
		{
		  $_=substr($pre,0,$#pre-1);
		  print_childs($plist[$i], $pre, "$_$T");
		}
	    }
	  $p0=$pre; chop $p0;
	  if(! $opt_G)
	    { print_childs($plist[$i], $pre, "$p0`-"); }
	  else
	    {
	      $_=$p0; chop;
	      print_childs($plist[$i], $pre, "$_$M");
	    }
	}
    }
  else { print"\n"; }
}